Application MS ACCESS dans le Cloud Storage

Le Cloud Storage, du fait de son fonctionnement par synchronisation de fichiers, ne permet pas les accès concurrents.

Pour aborder ce tutoriel, vous devez avoir de sérieuses connaissances en VBA et maîtriser l'utilisation des classes. Vous devez également maîtriser les tables liées, ainsi que la gestion des conflits.

Retrouvez un excellent tutoriel pour vous former aux classes VBA https://fauconnier.developpez.com/articles/vba/general/classes/.

Vous ne pouvez l'installer qu'à partir de Windows Vista en version 32 ou 64 bits. Plus d'informations sur cette page :

http://windows.microsoft.com/fr-FR/skydrive/system-requirements

Installable à partir de XP, il dispose d'une capacité de stockage de 5 Go gratuit.

Pour l'installer, rendez-vous sur votre iGoogle. GDrive est présent dans la barre de menu.

Dropbox propose 2 Go d'espace de stockage extensible. J'ai choisi cette solution pour illustrer ce cours.

Vous pouvez faire l'installation dès à présent en utilisant l'adresse suivante :

http://db.tt/luWcVhHB (gagnez 500 Mo supplémentaires en utilisant ce lien de parrainage)

À partir du lien indiqué plus haut, vous avez installé Dropbox sur votre poste. Le plug-in est chargé au démarrage de la session et on peut le contrôler via la barre des tâches.

Lors de l'installation, le dossier est créé par défaut dans le dossier de l'utilisateur.

Un raccourci vers ce dossier est également créé sur le bureau.

Le plug-in reste en mémoire jusqu'à sa fermeture et est accessible dans la barre des tâches. C'est lui qui observe les fichiers et les synchronise.

Notez qu'une liaison internet haut débit est obligatoire pour avoir un fonctionnement optimal.

Le seul inconvénient majeur et sûrement rédhibitoire pour certaines applications est de ne pas pouvoir l'appliquer à un fonctionnement multiutilisateur. En effet, comme il s'agit de synchronisation de fichiers, si plusieurs machines modifient le même fichier de données en même temps, il y aura conflit.

En cas de conflit, les fichiers ne sont pas perdus ; leur nom est complété par le nom de la machine et la date du conflit.

Voici un exemple de conflit sur deux fichiers.

Outre la gestion des conflits indiquée précédemment, un avantage non négligeable est la taille des fichiers. Dropbox bénéficie d'une marge confortable avec ses 10 Go maxi par fichier, soit bien au-delà d'un fichier Microsoft Access.

Vous disposez également d'un archivage des versions sur une durée de trente jours (extensible moyennant un abonnement payant) et également la possibilité de partager des répertoires individuellement.

Il convient de choisir une architecture frontale/dorsale pour éviter de synchroniser des informations inutiles, comme l'IHM.

N'hésitez pas à crypter la dorsale, Dropbox Inc. vous l'autorise.

Dès le démarrage et avant même tout accès à une des tables de la dorsale, l'application vérifie qu'un fichier, que nous appellerons « lock », existe dans le dossier synchronisé.

• Si ce n'est pas le cas, l'application le crée. Dès lors, le plug-in Dropbox l'envoie dans le Cloud, qui le renvoie vers les postes abonnés. L'application fonctionne normalement. À la fermeture, le fichier « lock » est effacé et le plug-in répercute l'action dans le Cloud.
• Si le fichier « lock » existe, l'application affiche un message et se ferme.

IV-A-1. Schéma de fonctionnement▲

Pourquoi utiliser un fichier dit « lock » au lieu d'utiliser directement le fichier  « laccdb » de la dorsale ?

La question mérite d'être posée. Le choix s'est porté sur un fichier texte pour pouvoir contrôler les homonymies de nom d'utilisateur.

Comme nous l'avons vu dans l'installation, le chemin Dropbox local comme l'utilisateur peuvent être différents d'un poste à l'autre. Une table locale à l'application est donc nécessaire pour stocker ces deux paramètres importants.

Créez une table dans l'application suivant cette structure :

Parametre contiendra le nom du paramètre et Valeur sa valeur. Cette table contiendra le paramètre CheminPartage qui donne le chemin vers la Dropbox locale et Utilisateurlocal, l'utilisateur local de l'application.

Inutile de la remplir, c'est le code qui s'en chargera.

Enregistrez-la sous le nom tiParametres. Le i indique que cette table est interne à l'application (fichier Frontal), par opposition à une table de paramètres qui serait stockée dans la dorsale.

Créez un module de classe nommé CCloud, n'oubliez pas de le paramétrer grâce aux propriétés comme l'indique la copie d'écran suivante.

Nous sommes fin prêts pour créer les attributs et les méthodes.

Voici le diagramme de classe CCloud qui permet d'en avoir une vue d'ensemble.

V-C-1. Attributs▲

V-C-2. Méthodes▲

L'en-tête est important dans une classe, car c'est là qu'on y retrouve les variables locales.

Option Compare Database
Option Explicit

Dim vStationLocale As String        ' nom de la station locale
Dim vCheminPartage As String        ' le chemin SkyDrive/DropBox/GDrive local
Dim vUtilisateurLocal As String     ' l'utilisateur local
Const cNomFichier As String = "occupe.txt"  'nom du fichier lock

La constante cNomFichier contient le nom du fichier « Lock ». Si ce nom ne vous convient pas vous pouvez très bien le modifier ; le fonctionnement n'en souffrira pas.

La méthode d'initialisation Class_Initialize contient l'initialisation de certaines variables comme le nom de l'utilisateur local ainsi que celui de la station.

La méthode Class_Terminate, qui s'exécute à la libération de la classe, permet de déclencher la méthode d'effacement du fichier « lock » et de contrôler un éventuel conflit.

Private Sub Class_Initialize()
' démarre la classe
  vStationLocale = Environ("ComputerName")
  'on fixe le nom de l'utilisateur si celui-ci n'existe pas.
  If vUtilisateurLocal = "" Then
     UtilisateurLocal = vStationLocale & ";" & Environ("UserName")
  End If
End Sub

Private Sub Class_Terminate()
'Fermeture de la classe
'à appeler sur le close du dernier formulaire ouvert ou avant un quit
' supprime le fichier lock
    EffacerFichier
End Sub

Certains attributs n'ont pas de Setter car ils renvoient des valeurs initialisées par la classe.

V-F-1. Le nom de la station locale - StationLocale▲

Public Property Get StationLocale() As String
    StationLocale = vStationLocale
End Property

V-F-2. L'utilisateur local - UtilisateurLocal▲

Public Property Let UtilisateurLocal(vLocalUser As String)
' définit l'utilisateur local à partir de
' nom d'utilisateur Windows +
On Error GoTo errSub

Dim db As DAO.Database
Dim rst As DAO.Recordset
Set db = CurrentDb
Set rst = db.OpenRecordset("tIParametres", dbOpenDynaset)
rst.FindFirst "Parametre='UtilisateurLocal'"
' le paramètre existe on le renseigne
If Not rst.NoMatch Then
   rst.Edit
   rst.Fields(2) = vLocalUser & "-" & Replace(CDbl(Now()), ".", "")
   rst.Update
Else
' il n'existe pas on le crée
   rst.AddNew
   rst.Fields(1) = "UtilisateurLocal"
   rst.Fields(2) = vLocalUser & "-" & Replace(CDbl(Now()), ".", "")
   rst.Update
End If

rst.Close

ExitSub:
  Set rst = Nothing
  Set db = Nothing
  On Error GoTo 0
  Exit Property

errSub:
  Resume Next 
End Property

PC-WINDOWS7;fabrice;412348217708333

Public Property Get UtilisateurLocal() As String
' renvoie l'utilisateur local si défini
On Error GoTo errSub
' renvoie la valeur de l'attribut demandé
Dim db As DAO.Database
Dim rst As DAO.Recordset

Set db = CurrentDb
Set rst = db.OpenRecordset("tIParametres", dbOpenSnapshot)
rst.FindFirst "Parametre='UtilisateurLocal'"
If Not rst.NoMatch Then
   UtilisateurLocal = Nz(rst.Fields("Valeur"), "")
Else
   UtilisateurLocal = ""
End If
rst.Close
ExitSub:
  Set rst = Nothing
  Set db = Nothing
  On Error GoTo 0
  Exit Property

errSub:
    GoTo ExitSub
End Property
End Property

V-F-3. Le chemin local de la Dropbox - CheminPartage▲

Public Property Let CheminPartage(vChemin As String)
' enregistre le chemin de partage
On Error GoTo errSub

Dim db As DAO.Database
Dim rst As DAO.Recordset
Set db = CurrentDb
Set rst = db.OpenRecordset("tIParametres", dbOpenDynaset)
rst.FindFirst "Parametre='CheminPartage'"
If Not rst.NoMatch Then
   rst.Edit ' enregistre le chemin de partage
   rst.Fields(2) = vChemin
   rst.Update
Else
   rst.AddNew  ' crée le paramètre
   rst.Fields(1) = "CheminPartage"
   rst.Fields(2) = vChemin
   rst.Update
End If
' stockage du chemin pour la classe
vCheminPartage = vChemin
rst.Close
ExitSub:
  Set rst = Nothing
  Set db = Nothing
  On Error GoTo 0
  Exit Property

errSub:
  Resume Next
End Property

Public Property Get CheminPartage() As String
' renvoie le chemin de partage si déjà défini
On Error GoTo errSub

If Len(vCheminPartage) <> 0 Then
   CheminPartage = vCheminPartage
   Exit Property
End If

Dim db As DAO.Database
Dim rst As DAO.Recordset
Set db = CurrentDb
Set rst = db.OpenRecordset("tIParametres", dbOpenSnapshot)
rst.FindFirst "Parametre='CheminPartage'"
If Not rst.NoMatch Then
   CheminPartage = Nz(rst.Fields("Valeur"), "")
Else
   CheminPartage = ""
End If

rst.Close

ExitSub:
  Set rst = Nothing
  Set db = Nothing
  On Error GoTo 0
  Exit Property

errSub:
    GoTo ExitSub
End Property

V-F-4. L'utilisateur connecté - UtilisateurConnecte▲

Public Property Get UtilisateurConnecte() As String
' retourne l'utilisateur qui est connecté actuellement
' celui-ci n'est pas forcément l'utilisateur local
On Error Resume Next ' une erreur peut se produire si le fichier lock
                     ' est fermé dans l'intervalle
    Dim vFile As Long
    Dim strLigne As String
    Dim strUtilisateur() As String
    
    If Dir(vCheminPartage & cNomFichier, vbNormal) <> "" Then
        vFile = FreeFile
        Open vCheminPartage & cNomFichier For Input As vFile
        Line Input #vFile, strLigne
        Close #vFile        ' Ferme le fichier.
    End If
    
    strUtilisateur = Split(strLigne, ";")
    UtilisateurConnecte = strUtilisateur(0) & ";" & strUtilisateur(1)
    
End Property

V-F-5. La détection de l'utilisation de l'application par un tiers - Occupe▲

Public Property Get Occupe() As Boolean
' Renvoie vrai si le fichier de lock existe
' et que l'utilisateur n'est pas le local
Dim vOccupe As Boolean
    vOccupe = Dir(vCheminPartage & cNomFichier, vbNormal) <> ""
    If vOccupe Then
       If UtilisateurConnecte = UtilisateurLocal Then
          vOccupe = False ' c'est la même connexion
       End If
    End If
    Occupe = vOccupe
End Property

V-F-6. La détection des conflits - Conflit▲

Pour détecter un conflit, il faut tester l'existence d'une copie de la base effectuée par le serveur Dropbox.

La copie se nommera ainsi :

Nom de la dorsale (copie de ^{Nom de la station} en conflit Date au format anglo-saxon).accdb

Un Dir donnera ceci :

 

Sélectionnez

Dir *Pc-windows7 en conflit 2012-11-21.accdb

En voici l'équivalent avec l'attribut de la classe.

 

Sélectionnez

Public Property Get Conflit() As Boolean
On Error GoTo errSub
Conflit = Dir(CDropb.CheminPartage & "*" & CDropb.StationLocale & " en conflit " & Format(Date, "yyyy-mm-dd") & ").accdb") <> ""
ExitSub:
  On Error GoTo 0
  Exit Property
errSub:
    GoTo ExitSub
End Property

Cet attribut est appelé depuis un formulaire muni d'un timer.

Il n'y a que deux méthodes à mettre en place pour parfaire la classe.

• Création du fichier  « lock ».
• Effacement du fichier « lock ».

Rien ne vous empêche de l'étoffer suivant vos besoins personnels.

V-G-1. Création du fichier - CreerFichier▲

Public Sub CreerFichier()
' création du fichier de lock
' composé de l'utilisateur local + date heure de connexion
    Dim vFile As Long
    Dim strLigne As String
    vFile = FreeFile
    strLigne = UtilisateurLocal & ";" & Format(Now(), "dddd dd mmmm yyyy hh:mm:ss")

    Open vCheminPartage & cNomFichier For Append As vFile
    Print #vFile, strLigne
    Close #vFile        ' Ferme le fichier.

End Sub

V-G-2. Effacement du fichier Lock - EffacerFichier▲

Private Sub EffacerFichier()
' efface le fichier (lors de la libération)
' uniquement si l'utilisateur actuel est l'utilisateur local
    If UtilisateurConnecte = UtilisateurLocal Then
       Kill vCheminPartage & cNomFichier
    End If
End Sub

À la fermeture de l'application, il faut libérer l'application en supprimant le fichier « lock ».

VI-A-1. Événement Sur Fermeture▲

Private Sub Form_Close()
    DoCmd.OpenForm "fAttente", , , , , acDialog
    Set CDropb = Nothing
    Doevents
    DoCmd.Quit
End Sub

Ce formulaire est composé des contrôles suivants :

• une cadre qui fait office de barre de progression ;
• une zone de titre ;
• une zone de message ;
• un bouton de commande.

Nous avons besoin d'une variable locale pour ce module. Elle est donc déclarée dans l'en-tête du module. Cette variable permettra de faire évoluer la barre de progression.

Option Compare Database
Option Explicit
Dim i As Long 'stocke le pas de progression pour la barre

VII-B-1. Sur Ouverture▲

Private Sub Form_Open(Cancel As Integer)
i = 500 'pas de progression
End Sub

VII-B-2. Le bouton Fermer▲

Private Sub btnFermer_Click()
    DoCmd.Close
End Sub

VII-B-3. Le Timer▲

Private Sub Form_Timer()

If Me.Barre.Width > i Then ' si la barre n'a pas atteint son dernier pas
    If Not CDropb.Conflit Then  ' si pas de conflit
       Me.Barre.Width = Me.Barre.Width - i  'progression de la barre
    Else
       ' si conflit
       Me.TxtMsg.Caption = "Vous avez créé un conflit d'écriture avec un autre utilisateur."
       Me.btnFermer.Visible = True 'on affiche le bouton
       Me.TxtMsg.Visible = True    ' on affiche le message
       Me.Barre.Visible = False    ' on cache la barre pour
       Me.TimerInterval = 0        ' on arrête le timer
    End If
Else
    DoCmd.Close ' on ferme automatiquement le formulaire si la progression est finie
End If

End Sub

Cette fonction renvoie la valeur passée avec un \ de terminaison.

Function fHasBackSlash(vlChemin As Variant) As String
'---------------------------------------------------------------------------------
' Procedure : fHasBackSlash
' Author    : Fabrice CONSTANS
' Date      : 01 / 06 / 2012
' Purpose   : s'il n'y a pas de backslash à la fin d'un chemin passé en référence, l'ajoute
' Parametres:
' - vlchemin    = le chemin à modifier
'--------------------------------------------------------------------------------
    On Error GoTo ExcfHasBackSlash
    ' teste si le caractère de la fin est un \
    If Right(Trim(vlChemin), 1) <> "\" Then
        ' l'ajoute
        fHasBackSlash = Trim(vlChemin) & "\"
    Else
        ' renvoie sans espace
        fHasBackSlash = Trim(vlChemin)
    End If
    On Error GoTo 0
    Exit Function

ExcfHasBackSlash:
    If Err.Number = 94 Then
        fHasBackSlash = "c:\"
        Exit Function
    End If

errSub:
    fHasBackSlash = False    ' une erreur quelconque se produit
End Function

Vous pouvez indiquer le chemin de la Dropbox pour y stocker des documents liés à l'application.

vgStrRepertoireDocument = fHasBackSlash(CDropb.CheminPartage) & "Documents Amap\"

La fonction fHasBackSlash() teste et ajoute l'antislash en fin de chaîne. Elle est présente dans l'annexe en fin du tutoriel.