Détection de modification dans un formulaire

En lecture la propriété « Dirty » indique l'état de l'enregistrement courant.

« False » indique que l'enregistrement n'est pas modifié.

« True » indique que l'enregistrement est modifié.

L'utilisation de « Dirty » est intéressante autant en lecture qu'en écriture.

Lorsque « Dirty » est à « True », donc que l'enregistrement est modifié, on peut lui affecter la valeur « False ». Dans ce cas l'enregistrement est sauvegardé.

On peut également affecter « True » lorsque la propriété « Dirty » est à « False ». Il ne se passe rien de particulier sinon que l'enregistrement est considéré comme modifié. Si le sélecteur du formulaire est visible le crayon apparait.

Lors de la saisie d'un nouvel enregistrement, on souhaite affecter une valeur dynamique à un contrôle pour que l'utilisateur n'ait pas à la saisir ou qu'il n'en ait tout simplement pas le contrôle.

La facilité serait d'utiliser une affectation à la valeur du contrôle. C'est ici qu'est le piège.

Le code ci-dessous démontre le changement d'état de la propriété « Dirty » suite à l'affectation.

Debug.Print Me.Dirty  'False
Me.NomUtilisateur.Value = Environ("UserName")
Debug.Print Me.Dirty  'true

Le premier état de la propriété est « False », c'est normal l'enregistrement vient d'être chargé. Une fois l'affectation réalisée l'état est à « True », cela reste vrai puisque l'enregistrement vient d'être modifié.

Si vous utilisez une colonne de type « NuméroAuto » celle-ci sera incrémentée, même si vous faites une annulation avec la méthode ou la commande « Undo ».

Pour ne pas tomber dans ce piège il faut utiliser la propriété « DefaultValue » (Valeur par défaut).

Private Sub Form_Open(Cancel As Integer)
Debug.Print Me.Dirty  'False
Me.NomUtilisateur.DefaultValue = """" & Environ("UserName") & """"
Debug.Print Me.Dirty  'False
End Sub

Il s'agit là du piège principal de la propriété  « Dirty ».

Il faut également faire attention aux événements éponymes qui sont trompeurs. Ce tableau indique la modification de l'état de la propriété « Dirty» tout au long des événements.

On peut voir que lors des événements « Dirty» d'un contrôle et d'un formulaire, la propriété « Dirty» ne passe pas à « True ». On rencontre souvent cette erreur due essentiellement à une interprétation au lieu d'un apprentissage.

Pour en savoir plus sur ces événements vous pouvez vous référer au tutoriel suivant :

Les événements avec Microsoft Access : Les Formulaires

Ce code met en lumière le cas classique de l'enregistrement d'une fiche. On teste d'abord si l'enregistrement a été modifié.

Private Sub btnEnregistrer_Click()
' enregistre la fiche courante
    If Me.Dirty Then ' Est-elle modifiée ?
        DoCmd.RunCommand acCmdSaveRecord
    End If
End Sub

La possibilité d'annuler la modification en cours est importante pour les utilisateurs qui ne sont pas habitués à la touche « Echap». Comme pour la sauvegarde on teste d'abord si la fiche a été modifiée.

Private Sub btnAnnuler_Click()
' annule la modification
    If Me.Dirty Then Me.Undo
End Sub

Lors du changement d'enregistrement, on peut être amené à vérifier que l'enregistrement est en cours de modification. L'événement  « Form_Current » (Sur activation) permet de détecter ce changement d'enregistrement. On teste l'état de la propriété « Dirty », si elle est à « True » on affiche le message.

Private Sub Form_Current()
    If Me.Dirty Then  ' Est-elle modifiée ?
       If MsgBox("Souhaitez-vous enregistrer les modifications ?", vbExclamation + vbYesNo + vbDefaultButton2) = vbYes Then
           DoCmd.RunCommand acCmdSaveRecord
       End If
    Endif 
End Sub

De même lorsqu'on veut créer une nouvelle fiche, il est important de savoir si l'actuelle est en cours de modification ou encore si elle est valide.

Dans l'événement « Sur Clic » d'un bouton « Créer » on peut imaginer le double contrôle ; fiche modifiée et fiche valide.

Private Sub btnCreer_Click()
    If Me.Dirty Then ' Est-elle modifiée ?
        If Not ficheValide() Then ' Est-elle valide ?
            Exit Sub ' Je reste sur la fiche
        Else
           Me.Dirty = False ' Je sauvegarde.      
        End If
    End If
    DoCmd.GoToRecord , , acNewRec  ' modifiée et valide
    End Sub

Lors de la fermeture d'un formulaire, c'est l'occasion de connaitre les intentions de l'utilisateur. Le prévenir que la fiche est en cours de modification peut faire toute la différence.

Private Sub BtnFermer_Click()
    If Me.Dirty Then ' Est-elle modifiée ?
       If MsgBox("Souhaitez-vous enregistrer les modifications ?", vbExclamation + vbYesNo + vbDefaultButton2) = vbYes Then
        If ficheValide() Then ' Est-elle valide ?
           Me.Dirty = False ' Je sauvegarde.
        Else
           Exit Sub  ' J'abandonne la fermeture.
        End If
    End If
    DoCmd.Close  ' Je ferme le formulaire.
    Exit Sub