Les événements avec Microsoft Access

Se produit lorsqu'un formulaire est ouvert, mais avant l'affichage du premier enregistrement.
Au cours de cet événement vous pouvez agir sur les contrôles du formulaire : placer le focus sur un contrôle particulier, définir ou modifier une source de données.

Private Sub Form_Open(Cancel As Integer)
   Me.btnSelectionner.Visible = CurrentProject.AllForms("frmOuvrages").IsLoaded
   Me.btnFermer.Caption = Iif(CurrentProject.AllForms("frmOuvrages").IsLoaded,"Annuler","Fermer")
   Me.btnRendu.Visible = (Not CurrentProject.AllForms("frmOuvrages").IsLoaded)
End Sub

Dans l'exemple précédent le formulaire frmOuvrages conditionne l'affichage des boutons btnFermer et btnSelectionner ainsi que l'affichage d'un texte dans la légende du bouton btnFermer.

Se produit lorsqu'un formulaire est ouvert et que ses enregistrements sont affichés.
Identique au précédent mais ne se produit qu'une seule fois.

Se produit lorsque le formulaire change de dimension, soit par l'action de l'utilisateur sur le cadre du formulaire, soit lorsqu'il s'affiche à l'ouverture ou soit qu'il est redimensionné par le code.
L'événement se produit une fois à chaque pas de la souris.

Se produit lorsque le formulaire devient la fenêtre active.

Se produit lorsque le focus passe à un enregistrement donné pour en faire l'enregistrement activé, ou lorsque le formulaire est actualisé ou qu'il fait l'objet d'une nouvelle requête. On l'utilise largement pour modifier la présentation ou activer/désactiver des contrôles.

Ne pas confondre avec l'événement Sur activé - Form_Activate.

Source de données obligatoire.

Dans l'exemple suivant on utilise l'événement pour changer l'aspect d'un contrôle suivant sa valeur.

Private Sub Form_Current()
   If Me.Type = "Formateur" Then
      Me.Type.BackColor = RGB(255, 255, 0) 'jaune
   Else
      Me.Type.BackColor = RGB(255, 255, 255)  'blanc
   End If
End Sub

Se produit lorsque le formulaire est fermé mais toujours à l'écran. Il peut être provoqué par toutes actions de fermeture du formulaire, de sa mise en mode création (design), de la fermeture de l'application, d'ACCESS ou de Windows. On peut demander une confirmation de fermeture sur cet événement mais pas sur les suivants.

Prise en charge de l'annulation.

Dans l'exemple suivant on demande la confirmation à l'utilisateur avant de fermer le formulaire. Si l'utilisateur répond Non l'événement est annulé et le processus de fermeture est stoppé.

Private Sub Form_Unload(Cancel As Integer)
    If MsgBox("Souhaitez-vous fermer le formulaire ?", vbYesNo, "titre") = vbNo Then Cancel = True
End Sub

Se produit chaque fois que le formulaire perd le focus. Il se trouve alors dans un état désactivé.

Se produit lors de la fermeture du formulaire et qu'il est supprimé de l'écran. Cet événement ne peut être annulé. C'est le dernier événement de la chaîne de fermeture.

Lorsqu'un ordre de fermeture est donné au formulaire, trois événements s'enchaînent.

Se produit avant que les données d'un nouvel enregistrement ne soient enregistrées. Cet événement est souvent utilisé pour demander à l'utilisateur de confirmer l'ajout de données.

Source de données obligatoire.

Prise en charge de l'annulation.

Dans l'exemple suivant on propose la demande de confirmation à l'utilisateur pour la création de l'enregistrement. Si celui-ci clique sur Non la création est annulée.

Private Sub Form_BeforeInsert(Cancel As Integer)
   If MsgBox("Souhaitez-vous réellement créer cet enregistrement ?", vbYesNo, "Titre") = vbNo Then
      Cancel = True
   End If
End Sub

Se produit après l'ajout d'un nouvel enregistrement.

Source de données obligatoire.

Se produit avant que les données modifiées d'un enregistrement soient mises à jour.

Cet événement peut être utilisé pour contrôler la validité des données avant l'enregistrement.

Source de données obligatoire.

Prise en charge de l'annulation.

Se produit après que les données modifiées d'un enregistrement ont été mises à jour.

Source de données obligatoire.

Se produit avant le message de confirmation de la suppression d'un enregistrement.

Source de données obligatoire.

Prise en charge de l'annulation.

Contrôle du message ACCESS possible.

Se produit avant la suppression d'un enregistrement.

Source de données obligatoire.

Prise en charge de l'annulation.

Se produit après chaque suppression d'un enregistrement.

Paramètre Status :

• acDeleteOk (effacement effectué),
• acDeleteCancel (effacement annulé par programme),
• asDeleteUserCancel (effacement annulé par l'utilisateur)

Source de données obligatoire.

Se produit lorsque l'utilisateur annule une modification. L'événement est déclenché par l'appui sur la touche ESC (Echap), par un bouton d'annulation déclaré comme tel ou encore par la méthode d'annulation.

Me.Undo

Se produit lors de la modification de la valeur d'un enregistrement. On peut connaître cet état en consultant la propriété Dirty

Me.dirty

Notez que si vous modifiez par code l'enregistrement, que vous initialisez les champs d'un nouvel enregistrement ou que vous déclarez une source de données par programme, la propriété Dirty sera vrai.

Source de données obligatoire.

Se produit lorsque le formulaire reçoit le focus. Lorsque vous êtes sur un autre objet ou une autre application et que vous cliquez sur le formulaire.

Se produit lorsque le formulaire perd le focus. Le focus est reçu par un autre objet généralement un autre formulaire ou état.

Se produit lorsque l'utilisateur appuie puis relâche le bouton gauche de la souris sur le sélecteur du formulaire. Se produit également au premier clic d'un double-clic. Ne se produit ni si l'utilisateur clique sur un contrôle ou une section du formulaire, ni sur les éléments comme la barre de titre ou la barre d'état et autre ascenseur.

Se produit lors du deuxième clic dans la période fixée par le réglage de la souris dans le panneau de configuration de Windows. Il succède obligatoirement à l'événement Sur clic (form_click).

Prise en charge de l'annulation.

Se produit lors de l'appui sur un bouton de la souris. On peut connaître le bouton ou la séquence de bouton+touche que l'utilisateur a utilisée ainsi que l'endroit où est positionné le pointeur de la souris grâce aux paramètres suivants.

Button représente le bouton pressé.

• acLeftButton bouton gauche de la souris.
• acRightButton bouton droit de la souris.
• acMiddleButton bouton du milieu de la souris.

Shift représente la touche morte enfoncée au moment du clic.

• acShiftMask Masque de bits pour la touche MAJ.
• acCtrlMask Masque de bits pour la touche CTRL.
• acAltMask Masque de bits pour la touche ALT.

X et Y représente la position X et Y du pointeur. Valeur en twips par rapport au bord haut-gauche du formulaire.

Dans l'exemple suivant un message très secret s'affiche lorsque l'utilisateur clique dans une zone du Détail avec le bouton gauche tout en maintenant les 3 touches mortes. Le clic doit être fait dans un rectangle déterminé par X et Y.

Private Sub Détail_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
   'GetInput "Détail", "Détail_MouseDown", "Sur souris appuyée", Button, Shift, X, Y
    If Button = acLeftButton And Shift = acShiftMask + acCtrlMask + acAltMask And X > 200 And Y < 1000 Then
       MsgBox "Ce message est top secret !"
    End If
End Sub

Se produit lorsqu'un bouton de la souris est relâché. Cet événement survient immédiatement après l'événement Sur souris appuyée. Il est doté des mêmes paramètres que MouseDown

Se produit lors du déplacement du pointeur de la souris. Il est doté des mêmes paramètres que MouseDown.

Se produit lors de l'appui sur une touche ou d'une séquence de touches ou lors de l'envoi par code (Sendkeys ou EnvoiTouche). Cet événement possède des paramètres permettant de connaître la combinaison de touches pressées et d'intervenir dessus.

1. KeyCode indique la touche frappée. Vous pouvez utiliser les constantes de touches VbKeyXXX ou leur code ASCII/ANSI.
2. Shift indique si une touche morte est activée lors de l'appui. Syntaxe identique à celle des événements Mouse.

L'utilisation des événements de type Key ne fonctionne que si la propriété Aperçu Touches (KeyPreview) du formulaire est à Oui. Si vous souhaitez annuler la frappe utilisez la syntaxe suivante.

KeyCode = 0

Vous pouvez également la substituer en affectant le code de substitution au paramètre KeyCode.

Se produit lorsque la touche est relâchée. Identique au fonctionnement précédent.

Se produit lorsque la touche est enfoncée. Identique au fonctionnement précédent.

Les événements se produisent suivant ce diagramme.

Si l'utilisateur maintient la touche appuyée cette séquence se répète jusqu'au relâchement de la touche.

Se produit lors de l'action sur la roulette de la souris. On peut contrôler l'effet de la roulette en agissant sur les paramètres de l'événement.

• Page indique si la page est modifiée True / False.
• Count indique le nombre de lignes qui défile lors de l'action.

Se produit lorsque l'utilisateur sollicite le Filtre par formulaire.

Se produit au moment de l'application du filtre. Il entraîne d'autres événements dont ceux du contrôle qui reçoit le focus. Le contrôle actif perd le focus lors du clic sur le ruban, puis la pose du filtre se déclenche et le focus revient sur le contrôle. Notez que si le filtre est posé par le code il n'y a pas de perte/reprise de focus sur le contrôle.

Dans l'exemple suivant on empêche l'utilisateur d'enlever le filtre.

Private Sub Form_ApplyFilter(Cancel As Integer, ApplyType As Integer)
If ApplyType = acShowAllRecords Then
   Cancel = true 
Endif   
End Sub

Seul événement à ne pas être déclenché par une action de l'utilisateur, le timer permet de lancer la procédure toutes les n millisecondes. L'intervalle est défini par la propriété TimerInterval du formulaire. Cet intervalle est compris entre 0 ; pas de déclenchement, et 2.147.483.647 millisecondes soit presque 25 jours ! On peut attribuer cet intervalle par programme. Cela permet de bloquer le processus (0) ou de le réactiver (>0).

Dans cet exemple on affiche l'heure dans une zone de texte nommée Heure.

Me.Heure = Format(Now(), "hh:mm:ss")

La propriété Intervalle est réglée sur 2500 millisecondes.

Si vous souhaitez intégrer une horloge il en existe de très belle en Flash. Vous pouvez intégrer très facilement un composant Flash en insérant un contrôle ActiveX dans le formulaire.

J'utilise systématiquement le Timer pour mes mes splash screen.

Se produit lorsqu'on clique sur une zone de la section qui ne contient aucun contrôle. Son fonctionnement est identique à l'événement éponyme du formulaire.

Identique à l'événement éponyme du formulaire.

Se produit lorsqu'un bouton de la souris est enfoncé.

Se produit lorsqu'un bouton de la souris est relâché.

Se produit lorsque le pointeur de la souris est déplacé.

Se produit lors d'une modification de l'affichage même partiel de la section.
Quelques cas :

• Fermeture ou déplacement d'une fenêtre masquant même partiellement la section. Il est à noter que même si l'application n'est pas active et que la fenêtre masquant ne fait pas partie de celle-ci l'événement se produit.
• Lorsque le curseur passe d'un contrôle à un autre.
• Ne se produit pas lorsqu'un menu contextuel est affiché ou effacé.
• Ne se produit pas lorsque le focus passe d'une fenêtre contiguë mais pas chevauchante, à une autre.

L'événement clic sur une étiquette semble inutile à première vue mais un bon exemple est celui de la mise en place d'un tri sur le champ.

Private Sub EtNumero_Click()
    Me.OrderBy = "Numero  ASC"
    Me.OrderByOn = True
End Sub

Il s'agit là d'un code non finalisé, il faudra imaginer un système d'inversion (ASC, DESC et non trié) et pourquoi pas l'affichage de symboles pour identifier le tri en cours.

Le double-clic se déclenche au deuxième clic, le premier étant pris en charge par l'événement précédent.

Prise en charge de l'annulation.

Si une action dans l'événement Clic interrompt l'enchaînement comme une attente d'une réponse de la part de l'utilisateur, le message box (msgbox) étant un bon exemple, cet événement ne se produira pas.

Se produit lors du clic dans le contrôle ou sur l'étiquette liée. Pour lier une étiquette à un contrôle éligible vous devez :

• Sélectionner l'étiquette et faire un ctrl+X
• Sélectionner le contrôle et faire un ctrl+V

Se produit avant la mise à jour de la valeur contenue dans le contrôle.

Se produit après avoir choisi une nouvelle valeur de la liste ou après la saisie d'une nouvelle valeur. On utilise souvent cet événement pour effectuer des rafraîchissements de contrôle dépendant de la valeur de la liste. Dans l'exemple suivant la liste permet de filtrer une autre liste.

Private Sub cbo_AfterUpdate()
    Me.ListeFiltree.Requery
End Sub

Se produit quand le contenu de l'enregistrement est modifié. Soit parce que l'utilisateur a choisi une valeur de la liste soit qu'il a saisi un caractère.

Se produit lorsque l'utilisateur effectue un changement dans la zone de texte de la liste. L'événement se produit à la première frappe d'une touche du clavier (suppression, saisie, remplacement par un caractère différent) modifiant la valeur de la zone. Dans l'exemple suivant on calcule le nombre de caractères saisis. S'il y a dépassement un message d'affiche. 

Dim lenmax As Byte
lenmax = Len(Me.cbo.Text)
If lenmax > 15 Then
   MsgBox "Attention vous dépassez le nombre de caractères autorisés pour ce champ !"
   Me.cbo.Text = Left(Me.cbo.Text, 15)
End If

Vous pouvez remarquer que l'on ne teste pas la propriété Value ou le contrôle pour connaître le contenu mais la propriété Text. En effet seule cette propriété est à même de retourner une saisie en cours mais pas validée.

Se produit lorsque l'utilisateur saisit une nouvelle valeur dans la zone de liste déroulante. La propriété Limité à liste (LimitToList) doit être réglée sur Oui.

NewData contient le texte saisi par l'utilisateur.

Response gère le message et le comportement d'ACCESS.

• acDataErrDisplay affiche le message d'ACCESS
• acDataErrContinue n'affiche pas le message d'ACCESS
• acDataErrAdded n'affiche pas le message d'ACCESS et permet le rajout de la valeur à la liste. ACCESS réactualise seul la liste.

Dans l'exemple suivant nous utilisons le paramètre acDataErrAdded pour rajouter la nouvelle entrée à la table source de la zone de liste.

Dim rst As DAO.Recordset
Response = acDataErrAdded
    Set rst = CurrentDb.OpenRecordset("tblFonction", dbopendynaset)
    rst.AddNew
    rst.Fields("Metier") = NewData
    rst.Update
rst.Close
Set rst = Nothing

Se produit à la réception du focus par le contrôle. On utilise souvent cet événement pour dérouler automatiquement la liste comme dans l'exemple ci-dessous.

Private Sub cbo_GotFocus()
    Me.cbo.Dropdown
End Sub

Se produit à l'entrée dans la liste après que le focus ait été reçu.

Se produit après la perte du focus.

Prise en charge de l'annulation.

Parmi les quelques événements du contrôle d'onglet le plus important est bien celui-ci. En effet lorsque vous cliquez sur un des onglets c'est celui-ci qui se produit. Paradoxalement clic et double-clic ne se produisent que lorsque vous cliquez hors des onglets. Pour illustrer cet événement voici une petite astuce pour déclencher une action lors du clic sur un onglet particulier. Dans l'exemple il s'agit de quitter l'application.

If Me.CtlTab0.Pages.Item(Me.CtlTab0).Caption = "Quitter" Then
    If MsgBox("Etes-vous sûr(e) de vouloir quitter ?", vbYesNo + vbDefaultButton1, "info") = vbYes Then
       DoCmd.Quit
    Else
       Me.Page1.SetFocus
    End If
End If

Ce code est tiré de l'application DVDTek.