Créer une table des matières pour chacun de vos états

Le mécanisme de création doit permettre à chaque impression d'enregistrer en même temps qu'une référence, un numéro de page et un type (Titre, Sous-titre, Item).
L'enregistrement peut se faire à l'aide d'une requête, mais pour plus de confort, nous utiliserons les objets d'accès aux données (ADO).
L'utilisation de l'évènement Sur impression pourrait faire l'affaire, mais nous ne pourrions pas faire d'aperçu avant impression de la table des matières avant d'avoir imprimé l'état émetteur.
L'évènement Au formatage nous permettra de créer la table des matières directement à l'aperçu.

Pour éviter la redondance de code et permettre d'exporter rapidement cette fonctionnalité dans n'importe quelle application, nous allons créer une procédure générique.
Ouvrez un module.
Entrez le code suivant :

Sub fc_GenereTM(fc_Item As String, fc_Pge As Integer, fc_Typ As String)
Dim rst As Recordset

Set rst = CurrentDb.OpenRecordset("tbl_TableMat", dbOpenDynaset)

rst.FindFirst "tm_Item=""" & fc_Item & """"

If rst.NoMatch Then
   rst.AddNew                   ' ajout nouvel enregistrement
   rst!tm_item = fc_Item        ' écrit dans le champ
   rst!tm_page = fc_Pge
   rst!tm_type = fc_Typ
   rst.Update                       ' sauvegarde
Else
   If rst!tm_page < fc_Pge Then    ' problème signalé par
      rst.Edit
      rst!tm_page = fc_Pge         ' on met à jour la page
      rst.Update
   End If
End If

rst.Close                       ' ferme

End Sub

La procédure fc_GenereTM écrit la référence, la page et le type dans notre table tbl_TableMat.
J'ai procédé à la correction d'une erreur importante signalée par Olivera. En effet il apparaît que le dernier item de la page est enregistré avec le numéro de la page précédente. C'est la partie du code figurant après le Else qui gère ce problème. Il semble que l'enregistrement soit préparé avant que la place sur la page courante ne soit vérifiée. Pour preuve le 1er FormatCount (=1) indique la page précédente, le 2e FormatCount (=2) indique la bonne page.

Lorsque l'on remplit une table temporaire, il faut également songer à la vider. Nous allons créer une procédure à cet effet.

Sub fc_SupprTM()
Dim sql As String

DoCmd.SetWarnings False              ' pas de message de confirmation

sql = "DELETE * FROM tbl_TableMat;"  ' requête de suppression
DoCmd.RunSQL sql

DoCmd.SetWarnings True               ' message confirmation

End Sub

Cette procédure exécute une simple requête suppression totale sur la table tbl_TableMat.

Le module étant terminé, vous pouvez l'enregistrer sous le nom mdl_TableMat.

Avant tout, il convient de vider la table tbl_TableMat. Nous allons utiliser l'événement Avant ouverture pour cette opération. Cliquez dans le carré en haut à gauche de l'état.

Ouvrez la fenêtre de propriétés et cliquez sur l'onglet Évènement. Dans la propriété Avant ouverture, sélectionnez [Procédure événementielle] et ouvrez le module à l'aide du bouton suivant :

Insérez ce code :

fc_SupprTM

Le code est maintenant en place. À chaque ouverture de l'état, la table tbl_TableMat sera vidée.

La première information concerne le titre de la table des matières.
Cliquez sur la zone En-tête d'état et dans la fenêtre propriété, cliquez sur l'onglet Évènement. Dans la propriété Au formatage, sélectionnez [Procédure événementielle] et ouvrez le module correspondant.
Insérez ce code :

   fc_GenereTM Me.Titre.Caption, Me.Page, "T"       ' écriture dans la table "table des matières"

Le détail de chaque commande est commenté ci-dessous.

Faites un essai pour vérifier que la table tbl_tableMat est correctement renseignée.
Pour cela, cliquez sur l'icône d'aperçu avant impression, puis, avec la touche F11, faites apparaître la fenêtre Base de données. Cliquez sur l'onglet Table, puis sur l'objet tbl_TableMat.
Vous devriez voir ceci.

La génération du titre est terminée.

Cliquez sur l'état et passez en mode Création. Sélectionnez la zone d'En-tête de groupe Nom du produit. Dans la propriété Au formatage, sélectionnez [Procédure événementielle] et ouvrez le module.
Insérez ce code :

   fc_GenereTM Me.PremièreLettreDuNom, Me.Page, "ST"

Comme précédemment, chaque commande est commentée ci-dessous.

Vous noterez que le travail est répétitif, cela est essentiellement dû au fait que nous avons créé un code générique.

Pour les items, procédez de la même manière que pour les cas précédents, mais avec la zone Détails. Dans la procédure, insérez le code suivant :

   fc_GenereTM Me.Nom_du_produit, Me.Page, "I"

La partie qui génère la table des matières est terminée. La quantité de code nécessaire n'est pas très importante, comme vous pouvez le constater.

Créez un nouvel état.

Ajoutez une zone d'En-tête d'état. Menu Affichage/En-tête et pied de rapport.
À l'aide de la liste des champs, insérez dans l'En-tête d'état le champ tm_Item.
Changez les propriétés suivantes de tm_Item :

Réduisez la hauteur de l'En-tête de page et du Pied d'état le plus possible et le Pied de page de moitié.
Dans le Détail insérez les champs suivants :

• tm_Type ;
• tm_Item ;
• tm_Page.

Insérez une étiquette avec une série de points à intituler tm_Points.
Ajustez le tout pour avoir la présentation suivante :

Sélectionnez la totalité des champs du Détail un par un (Shift+clic gauche) et changer les propriétés suivantes :

Une fois cette mise en forme effectuée, passez à l'écriture du code.

Sélectionnez le Détail et créez une procédure événementielle sur la propriété Au formatage.
Dans la section des déclarations générales, créez les constantes suivantes :

Option Compare Database
Const Blanc = 16777215
Const Gris = 12632256

Ces constantes contiennent les couleurs gris et blanc, qui permettent d'alterner sous-titres et items dans le détail de l'état.
Dans la procédure Détail_Format entrez le code suivant :

' rend visible les contrôles et étiquettes
Me.tm_Item.Visible = True
Me.tm_Page.Visible = True
Me.tm_Points.Visible = True
' cache systématiquement tm_Type
Me.tm_Type.Visible = False
' La hauteur d'origine
Me.Détail.Height = 0.423    


' suivant le type T,ST,I
Select Case Me.tm_Type
       Case "T"     ' traitement du titre (ne doit pas apparaître dans détail)
            Me.tm_Item.Visible = False
            Me.tm_Type.Visible = False
            Me.tm_Page.Visible = False
            Me.tm_Points.Visible = False
            Me.Détail.Height = 0
       Case "ST"    ' traitement des sous-titres (apparaît en grisé)
            Me.tm_Item.FontSize = 10
            Me.tm_Item.FontBold = True
            Me.Détail.BackColor = Gris
       Case "I"     ' traitement des items (apparaît sur fond blanc)
            Me.tm_Item.FontSize = 8
            Me.tm_Item.FontBold = False
            Me.Détail.BackColor = Blanc        
End Select

Lorsque vous définissez la valeur d'une propriété, celle-ci reste en l'état jusqu'à son changement. C'est pour cette raison que le code suivant, exécuté pour chaque enregistrement, définit certaines propriétés systématiquement.

1. Le titre ne doit s'afficher que dans l'En-tête. Il sera affiché également dans la première ligne du Détail. C'est pourquoi nous devons obligatoirement le cacher et réduire le Détail pour ne pas laisser d'espaces disgracieux.
2. Les sous-titres sont grisés avec la propriété Backcolor.
3. Les items sont sur fond blanc toujours avec la propriété Backcolor.

Notez que les sous-titres et les items s'intercalent et qu'il convient de définir les propriétés à chaque passage.

Faites un essai en cliquant sur le bouton aperçu avant impression. Nous pouvons sauvegarder l'état.